Loop (文件和文件夹)

Loop, Files, FilePattern , Mode

Loop, FilePattern , IncludeFolders?, Recurse?

Loop, C:\My Documents\Address List.txt
    ShortPathName := A_LoopFileShortPath

if A_LoopFileAttrib contains H,R,S  ; 跳过具有 H(隐藏), R(只读) 或 S(系统) 属性的任何文件. 注意: 在 "H,R,S" 中不含空格.
    continue  ; 跳过这个文件并前进到下一个.

FileList := ""
Loop, Files, *.jpg
   FileList .= A_LoopFileName "`n"
Loop, Parse, FileList, `n
   FileMove, %A_LoopField%, renamed_%A_LoopField%

#1

Loop Files, %A_ProgramFiles%\*.txt, R  ; 递归子文件夹.
{
    MsgBox, 4, , Filename = %A_LoopFileFullPath%`n`nContinue?
    IfMsgBox, No
        break
}

#2: 计算文件夹的大小, 包括其所有子文件夹中的文件:

SetBatchLines, -1  ; 让操作以最快速度进行.
FolderSizeKB := 0
FileSelectFolder, WhichFolder  ; 让用户选取文件夹.
Loop, Files, %WhichFolder%\*.*, R
    FolderSizeKB += A_LoopFileSizeKB
MsgBox Size of %WhichFolder% is %FolderSizeKB% KB.

#3: 获取根据名称排序的文件名(要以日期排序请参阅下一个例子):

FileList := ""  ; 初始为空.
Loop, C:\*.*
    FileList .= A_LoopFileName "`n"
Sort, FileList, R  ; R 选项使得以逆序排列. 请参阅 Sort 了解其他选项.
Loop, parse, FileList, `n
{
    if (A_LoopField = "")  ; 忽略列表末尾的空项.
        continue
    MsgBox, 4,, File number %A_Index% is %A_LoopField%.  Continue?
    IfMsgBox, No
        break
}

#4: 获取根据修改日期排序的文件名:

FileList := ""
Loop, Files, %A_MyDocuments%\Photos\*.*, FD  ; 包含文件和子目录
    FileList .= A_LoopFileTimeModified "`t" A_LoopFileName "`n"
Sort, FileList  ; 根据日期排序.
Loop, Parse, FileList, `n
{
    if (A_LoopField = "")  ; 忽略列表末尾的最后一个换行符(空项).
        continue
    StringSplit, FileItem, A_LoopField, %A_Tab%  ; 用 tab 作为分隔符将其分为两部分.
    MsgBox, 4,, The next file (modified at %FileItem1%) is:`n%FileItem2%`n`nContinue?
    IfMsgBox, No
        break
}

#5: 仅复制比目标位置中它们的副本更新的源文件:

CopyIfNewer:
; 调用者已经为我们赋值了变量 CopySourcePattern 和 CopyDest.
Loop, Files, %CopySourcePattern%
{
    copy_it := false
    if not FileExist(CopyDest "\" A_LoopFileName)  ; 如果目标文件还不存在, 那么总是复制.
        copy_it := true
    else
    {
        FileGetTime, time, %CopyDest%\%A_LoopFileName%
        EnvSub, time, %A_LoopFileTimeModified%, seconds  ; 从目的时间中减去源文件的时间.
        if (time < 0)  ; 源文件比目的文件更新.
            copy_it := true
    }
    if copy_it
    {
        FileCopy, %A_LoopFileFullPath%, %CopyDest%\%A_LoopFileName%, 1   ; 以覆盖形式复制
        if ErrorLevel
            MsgBox, Could not copy "%A_LoopFileFullPath%" to "%CopyDest%\%A_LoopFileName%".
    }
}
Return

#6: 把通过命令行参数传递的文件名转换为长名称, 完整路径和在文件系统中存储的正确的大写/小写字符形式.

Loop %0%  ; 对于拖放到脚本上(或作为参数传递) 的每个文件.
{
    GivenPath := %A_Index%  ; 获取下一个命令行参数.
    Loop %GivenPath%, 1
        LongPath := A_LoopFileLongPath
    MsgBox The case-corrected long path name of file`n%GivenPath%`nis:`n%LongPath%
}